aardio中怎么获取拖入文件的小图标显示到界面然后保存到本地?

Admin  悬赏: 5 金币

发布:2018-05-05 16:30:31 分类:问答

import win.ui;

/*DSG{{*/

var winform = win.form(text="aardio form";right=573;bottom=352;acceptfiles=1)

winform.add(

button={cls="button";text="保存16*16的ico图标到硬盘";left=25;top=155;right=220;bottom=199;z=2};

plus={cls="plus";left=27;top=82;right=85;bottom=137;edge=1;z=1};

static={cls="static";text="拖入任何类型文件/文件夹/程序/文档/快捷方式,获取它的16*16图标";left=113;top=91;right=547;bottom=134;transparent=1;z=3}

)

/*}}*/



import win.imageList;

import console;



winform.wndproc = function(hwnd,message,wParam,lParam){

    select( message ) { 

        //拖入文件(exe程序/文件夹/文档/快捷方式等)

        case 0x233/*_WM_DROPFILES*/{

            shImageList = win.imageList.shell( 1)

            

            //console.varDump(shImageList.getIcon(1,1/*_ILD_TRANSPARENT*/))

            

            var ico = shImageList.getIcon(1,1/*_ILD_TRANSPARENT*/);//返回的是point类型数据

            winform.plus.background = ico//.copyHandle()

            console.varDump(ico)

        }

    }

    //无返回值则继续调用默认回调函数

}



winform.show() 

win.loopMessage();

• 泽越止    被采纳

  Time:2018-05-05 17:39:33

  import win.ui;
  
  /*DSG{{*/
  
  var winform = win.form(text="aardio form";right=573;bottom=352;acceptfiles=1)
  
  winform.add(
  
  button={cls="button";text="保存16*16的ico图标到硬盘";left=25;top=155;right=220;bottom=199;z=2};
  
  plus={cls="plus";left=27;top=82;right=85;bottom=137;edge=1;z=1};
  
  static={cls="static";text="拖入任何类型文件/文件夹/程序/文档/快捷方式,获取它的16*16图标";left=113;top=91;right=547;bottom=134;transparent=1;z=3}
  
  )
  
  /*}}*/
  
  
  
  import win.imageList;
  
  import fsys.info;
  
  import fsys.info;
  
  import console;
  
  import gdip.bitmap;
  
  
  
  var lst = win.imageList.shell( 1);
  
  
  
  var file;
  
  winform.onDropFiles = function(files){
  
      file = fsys.info.get(files[1],0x10/*_SHGFI_USEFILEATTRIBUTES*/ | 0x4000/*_SHGFI_SYSICONINDEX*/);
  
      lst.draw( file.iIcon, ::GetDC(winform.plus.hwnd), 0, 0,1/*_ILD_TRANSPARENT*/);
  
  }
  
  winform.button.oncommand = function(id,event){
  
      if(file){
  
          var bmp = gdip.bitmap(16,16);
  
          var dc = bmp.getGraphics().getDc();
  
          lst.draw( file.iIcon,dc, 0, 0,0/*_ILD_NORMAL*/);
  
          bmp.getGraphics().releaseDc(dc);
  
          bmp.save("c:\test.png");
  
      }
  
      
  
  }
  
  
  
  winform.show() 
  
  win.loopMessage();

• Admin    

  Time:2018-05-05 19:39:10
  已发十根火腿肠的微信红包答谢.欢迎各位码友踊跃作答,红包雨下个不停.
• Admin    

  Time:2018-05-05 19:49:29
  kio1同学也贡献了一种方法,比较简洁,但缺点是背景是灰色,不怎么知道弄成透明背景的png.同样感谢,发上来供大家交流学习:

  //获取文件图标
  
  import win.ui;
  
  /*DSG{{*/
  
  var winform = win.form(text="aardio form";right=573;bottom=352;acceptfiles=1)
  
  winform.add(
  
  button={cls="button";text="保存16*16的ico图标到硬盘";left=25;top=155;right=220;bottom=199;z=2};
  
  plus={cls="plus";left=27;top=82;right=85;bottom=137;edge=1;repeat="center";z=1};
  
  static={cls="static";text="拖入任何类型文件/文件夹/程序/文档/快捷方式,获取它的16*16图标";left=113;top=91;right=547;bottom=134;transparent=1;z=3}
  
  )
  
  /*}}*/
  
  
  
  import fsys.info
  
  import win.imageList
  
  import gdip.bitmap
  
  winform.onDropFiles = function(files){
  
      var sfi = fsys.info.get(files[1], 0x200/*_SHGFI_DISPLAYNAME*/ | 0x4000/*_SHGFI_SYSICONINDEX*/);
  
      var handle = win.imageList.shell( 1 ).getIcon(sfi.iIcon)//0/*_SHIL_LARGE*/ 是32*32   ;1是16*16
  
      winform.plus.setBackground(gdip.bitmap(handle,1).copyHandle())
  
  }
  
  
  
  winform.button.oncommand = function(id,event){
  
      winform.plus.background.save("C:\Users\Administrator\Desktop\test.png",100)
  
  }
  
  
  
  winform.show() 
  
  win.loopMessage();

  
  
• Admin    

  Time:2018-05-05 20:04:55
  kio1同学终于把它弄成透明背景的png了,可喜可贺:

  //获取文件图标
  
  import win.ui;
  
  /*DSG{{*/
  
  var winform = win.form(text="aardio form";right=573;bottom=352;acceptfiles=1)
  
  winform.add(
  
  button={cls="button";text="保存16*16的ico图标到硬盘";left=25;top=155;right=220;bottom=199;z=2};
  
  plus={cls="plus";left=27;top=82;right=85;bottom=137;edge=1;repeat="center";z=1};
  
  static={cls="static";text="拖入任何类型文件/文件夹/程序/文档/快捷方式,获取它的16*16图标";left=113;top=91;right=547;bottom=134;transparent=1;z=3}
  
  )
  
  /*}}*/
  
  
  
  import console;
  
  
  
  import fsys.info
  
  import win.imageList
  
  import gdip.bitmap
  
  winform.onDropFiles = function(files){
  
      var sfi = fsys.info.get(files[1], 0x200/*_SHGFI_DISPLAYNAME*/ | 0x4000/*_SHGFI_SYSICONINDEX*/);
  
      var handle = win.imageList.shell( 1 ).getIcon(sfi.iIcon)//0/*_SHIL_LARGE*/
  
      winform.plus.setBackground(gdip.bitmap(handle,1).saveToBuffer(".png"))
  
  }
  
  
  
  winform.button.oncommand = function(id,event){
  
      winform.plus.background.save("C:\Users\Administrator\Desktop\test.png",80)
  
  }
  
  
  
  winform.show() 
  
  win.loopMessage();